Upload files to "/"

build.gradle

@@ -0,0 +1,69 @@
+plugins {
+    id 'java'
+    id("io.github.goooler.shadow") version "8.1.7"
+}
+
+group = 'me.zepsizola'
+version = '2.3'
+def projectName = 'CustomJoinLeave'
+
+repositories {
+    mavenCentral()
+    maven {
+        name = "papermc-repo"
+        url = "https://repo.papermc.io/repository/maven-public/"
+    }
+    maven {
+        name = "sonatype"
+        url = "https://oss.sonatype.org/content/groups/public/"
+    }
+    maven {
+        url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/'
+    }
+}
+
+dependencies {
+    compileOnly "io.papermc.paper:paper-api:1.20-R0.1-SNAPSHOT"
+    //compileOnly "io.papermc.paper:paper-api:1.20.4-R0.1-SNAPSHOT"
+    compileOnly 'me.clip:placeholderapi:2.11.5'
+    compileOnly 'net.luckperms:api:5.4'
+    implementation("org.bstats:bstats-bukkit:3.0.2")
+}
+
+def targetJavaVersion = 17
+java {
+    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
+    sourceCompatibility = javaVersion
+    targetCompatibility = javaVersion
+    if (JavaVersion.current() < javaVersion) {
+        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
+    }
+}
+
+tasks.withType(JavaCompile).configureEach {
+    options.encoding = 'UTF-8'
+
+    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
+        options.release.set(targetJavaVersion)
+    }
+}
+
+processResources {
+    def props = [version: version]
+    inputs.properties props
+    filteringCharset 'UTF-8'
+    filesMatching('plugin.yml') {
+        expand props
+    }
+}
+
+shadowJar {
+    relocate('org.bstats', 'me.zepsizola.customjoinleave.bstats')
+    configurations = [project.configurations.runtimeClasspath]
+    mergeServiceFiles()
+    archiveBaseName.set(projectName)
+    archiveVersion.set(version)
+    archiveClassifier.set('')
+}
+
+build.dependsOn shadowJar